🧑 feat(nix): Auto gc; disable git tree dirty warning

Allows setting iconTheme globally.

flake.nix

@@ -48,6 +48,7 @@
           modules = [
             inputs.rose-pine.homeManagerModules.rose-pine
             ./modules/home/shellAbbrs.nix
+            ./modules/home/iconTheme.nix
             ./home
           ];
         };

home/appearance/default.nix

@@ -6,6 +6,11 @@
 
   rose-pine.pointerCursor.enable = true;
 
+  home.iconTheme = {
+    package = pkgs.kora-icon-theme;
+    name = "kora";
+  };
+
   fonts.fontconfig.defaultFonts.monospace = [ "Maple Mono NF" ];
 
   imports = [

home/appearance/gtk.nix

@@ -1,13 +1,10 @@
-{ pkgs, ... }:
+{ config, ... }:
 {
   gtk = {
     enable = true;
 
     rose-pine.enable = true;
 
-    iconTheme = {
-      package = pkgs.kora-icon-theme;
-      name = "kora";
-    };
+    gtk2.configLocation = "${config.xdg.configHome}/gtk-2.0/gtkrc";
   };
 }

home/default.nix

@@ -19,11 +19,21 @@
   # Tell nix what version it is.
   nix.package = pkgs.nix;
 
-  # Enable flakes.
-  nix.settings.experimental-features = [
-    "nix-command"
-    "flakes"
-  ];
+  nix = {
+    # Enable flakes.
+    settings.experimental-features = [
+      "nix-command"
+      "flakes"
+    ];
+
+    # Disable that annoying "git tree is dirty" warning.
+    extraOptions = ''
+      warn-dirty = false
+    '';
+
+    # Garbage collection.
+    gc.automatic = true;
+  };
 
   xdg.configFile."nixpkgs/config.nix".text = # nix
     ''

home/programs/bun.nix

@@ -0,0 +1,10 @@
+{ ... }:
+{
+  programs.bun = {
+    enable = true;
+
+    settings = {
+      telemetry = false;
+    };
+  };
+}

home/programs/tmux.nix

@@ -37,10 +37,6 @@
     plugins = with pkgs.tmuxPlugins; [
       {
         plugin = resurrect;
-        extraConfig = # tmux
-          ''
-            set -g @resurrect-capture-pane-contents 'on'
-          '';
       }
 
       {

home/services/dunst.nix

@@ -1,5 +1,4 @@
 {
-  pkgs,
   config,
   lib,
   ...
@@ -12,12 +11,6 @@
     # drop-in weirdness.
     rose-pine.enable = false;
 
-    # TODO: Set this globally and import it.
-    iconTheme = {
-      package = pkgs.kora-icon-theme;
-      name = "Kora";
-    };
-
     settings = lib.mkMerge [
       ### Rose Pine ###
       # TODO: Set this conditionally based on current theme.

modules/home/iconTheme.nix

@@ -0,0 +1,60 @@
+{ lib, config, ... }:
+
+with lib;
+
+let
+  # https://github.com/nix-community/home-manager/blob/master/modules/misc/gtk.nix
+  iconThemeType = types.submodule {
+    options = {
+      package = mkOption {
+        type = types.nullOr types.package;
+        default = null;
+        example = literalExpression "pkgs.gnome.adwaita-icon-theme";
+        description = ''
+          Package providing the icon theme. This package will be installed
+          to your profile. If `null` then the theme
+          is assumed to already be available in your profile.
+        '';
+      };
+
+      name = mkOption {
+        type = types.str;
+        example = "Adwaita";
+        description = "The name of the icon theme within the package.";
+      };
+    };
+  };
+in
+{
+  options = {
+    home = {
+      iconTheme = mkOption {
+        type = types.nullOr iconThemeType;
+        default = null;
+        description = ''
+          The icon theme to use.
+        '';
+      };
+    };
+  };
+
+  config =
+    let
+      cfg = config.home.iconTheme;
+    in
+    {
+      gtk = mkIf config.gtk.enable (mkDefault {
+        iconTheme = {
+          name = cfg.name;
+          package = cfg.package;
+        };
+      });
+
+      services.dunst = mkIf config.services.dunst.enable (mkDefault {
+        iconTheme = {
+          name = cfg.name;
+          package = cfg.package;
+        };
+      });
+    };
+}