8dc6a9eb6e
* chore: update dev flake inputs
Flake lock file updates:
• Updated input 'call-flake':
'github:divnix/call-flake/4ff3ef19aee2c030cf0986508711ba19ba006375' (2024-01-07)
→ 'github:divnix/call-flake/db0ceba665a4525ecabbd3ca7c67c2540a3c1cc7' (2024-03-10)
• Updated input 'home-manager':
'github:nix-community/home-manager/93e804e7f8a1eb88bde6117cd5046501e66aa4bd' (2024-01-11)
→ 'github:nix-community/home-manager/2f0db7d418e781354d8a3c50e611e3b1cd413087' (2024-03-13)
• Updated input 'nixpkgs':
'github:NixOS/nixpkgs/317484b1ead87b9c1b8ac5261a8d2dd748a0492d' (2024-01-08)
→ 'github:NixOS/nixpkgs/0ad13a6833440b8e238947e47bea7f11071dc2b2' (2024-03-12)
* chore: update nvfetcher sources
* fix: pin call-flake
---------
Co-authored-by: github-actions[bot] <github-actions[bot]@users.noreply.github.com>
Co-authored-by: seth <getchoo@tuta.io>
67 lines
1.9 KiB
Nix
67 lines
1.9 KiB
Nix
{
|
|
description = "Soothing pastel theme for Nix";
|
|
|
|
inputs = {
|
|
nixpkgs.url = "nixpkgs/nixos-unstable";
|
|
|
|
home-manager = {
|
|
url = "github:nix-community/home-manager";
|
|
inputs.nixpkgs.follows = "nixpkgs";
|
|
};
|
|
|
|
# https://github.com/divnix/call-flake/issues/4
|
|
call-flake.url = "github:divnix/call-flake/a9bc85f5bd939734655327a824b4e7ceb4ccaba9";
|
|
};
|
|
|
|
outputs = { self, nixpkgs, call-flake, ... }@inputs:
|
|
let
|
|
systems = [
|
|
"x86_64-linux"
|
|
"aarch64-linux"
|
|
"x86_64-darwin"
|
|
"aarch64-darwin"
|
|
];
|
|
|
|
inherit (nixpkgs) lib;
|
|
|
|
forAllSystems = fn: lib.genAttrs systems (s: fn nixpkgs.legacyPackages.${s});
|
|
ctp = call-flake ../.;
|
|
in
|
|
{
|
|
checks = forAllSystems (pkgs: lib.optionalAttrs pkgs.stdenv.isLinux {
|
|
module-vm-test = pkgs.nixosTest (import ../test.nix { inherit ctp inputs; });
|
|
});
|
|
|
|
formatter = forAllSystems (pkgs: pkgs.nixpkgs-fmt);
|
|
|
|
packages = forAllSystems (pkgs:
|
|
let
|
|
eval = module: lib.evalModules {
|
|
modules = [
|
|
module
|
|
{
|
|
_module.check = false;
|
|
}
|
|
];
|
|
};
|
|
|
|
mkDoc = name: module:
|
|
let
|
|
doc = pkgs.nixosOptionsDoc {
|
|
options = lib.filterAttrs (n: _: n != "_module") (eval module).options;
|
|
documentType = "none";
|
|
revision = builtins.substring 0 8 self.rev or "dirty";
|
|
};
|
|
in
|
|
pkgs.runCommand "${name}-module-doc.md" { } ''
|
|
cat ${doc.optionsCommonMark} > $out
|
|
'';
|
|
in
|
|
{
|
|
nixos-doc = mkDoc "nixos" ctp.nixosModules.catppuccin;
|
|
home-manager-doc = mkDoc "home-manager" ctp.homeManagerModules.catppuccin;
|
|
|
|
default = self.packages.${pkgs.system}.home-manager-doc;
|
|
});
|
|
};
|
|
}
|